Prerequisites

1. Your organization has the sFiles Enterprise license.
2. sFiles is set up in your org.
3. Familiarity with the Salesforce REST API

Audience

This document is intended to be used by a Salesforce Administrator with experience developing backend functionality with Apex and REST API.

Overview

This document covers how to setup Apex Rest Calls with the sFiles Client API and Salesforce REST API. It does this by providing an example using the sFiles Client API method, "createFolder".
 

Steps to Create a sFiles REST Resource

1. Create an Apex class with the @RestResource annotation to expose it as a REST Resource .
2. In this class, initialize the sFiles Client API and populate the namedCredentialName, sharepointSiteId and documentLibraryId fields with the relevant information.
   1. See the sFiles API documentation for instructions on how to initialize the sFiles Client API.
3. Call the desired sFiles method with the parameter(s) received from the REST callout.
   1. See the sFiles API documentation for all available methods.
4. Return a JSON response that confirms the outcome of the callout.

View Salesforce's Apex REST Code Samples for further examples on how to create your specific REST resource.

sFiles REST Resource Example

The code snippet below gives an example of a POST REST Resource using the sFiles API method, "createFolder". See the sFiles Client API documentation to better understand the parentFolderId and folderName parameters of this method.

@RestResource(urlMapping='/sFiles/CreateFolder')
global with sharing class CreateFolder {
 
    @HttpPost
    global static fileforcem1.SharePointFileInfo createSpFolder(string parentFolderId, string folderName, string objectSettingName) {
        //get the SharePoint Settings MDT
        fileforcem1__SharePoint_Settings__mdt orgSettings = [SELECT fileforcem1__Named_Credential__c,fileforcem1__Document_Library_Id__c,fileforcem1__Site_Id__c FROM fileforcem1__SharePoint_Settings__mdt WHERE Developername = 'Default' limit 1];
        //get the SharePoint Object Settings MDT
        fileforcem1__SharePoint_Object_Settings__mdt objectSettings = [SELECT fileforcem1__Named_Credential__c,fileforcem1__Root_Folder_Id__c,fileforcem1__Site_Id__c,fileforcem1__Document_Library_Id__c FROM fileforcem1__SharePoint_Object_Settings__mdt WHERE MasterLabel =:objectSettingName LIMIT 1 ];
        //Initialize the client object
        fileforcem1.ClientApi clapi = new fileforcem1.ClientApi();
        String namedCredentialName;
        String sharepointSiteId;
        String documentLibraryId;
        //Set the named credential
        if(objectSettings.fileforcem1__Named_Credential__c != null) {
            namedCredentialName = objectSettings.fileforcem1__Named_Credential__c;
        } else {
            namedCredentialName = orgSettings.fileforcem1__Named_Credential__c;
        }
        //Set the site
        if(objectSettings.fileforcem1__Site_Id__c != null) {
            sharepointSiteId = objectSettings.fileforcem1__Site_Id__c;
        } else {
            sharepointSiteId = orgSettings.fileforcem1__Site_Id__c;
        }
        //Set the document library
        if(objectSettings.fileforcem1__Document_Library_Id__c != null) {
            documentLibraryId = objectSettings.fileforcem1__Document_Library_Id__c;
        } else {
            documentLibraryId = orgSettings.fileforcem1__Document_Library_Id__c;
        }
        //Insert values into client object
        clapi.namedCredentialName = namedCredentialName;
        clapi.sharepointSiteId = sharepointSiteId;
        clapi.documentLibraryId = documentLibraryId;
        try{
            fileforcem1.SharePointFileInfo newFolder = clapi.createFolder(parentFolderId, folderName);
            return newFolder;
        }
        catch(fileforcem1.ApiException error) {
            RestResponse res = RestContext.response;
            res.statusCode = error.httpStatusCode;
            return null;
        }
    }
}

sFiles REST Callouts

In order to utilize the REST resource above, you will need to create a callout. See below for examples on how to call the REST resource from a client command-line window:

Callout from a client command-line window Example

See the below example for how to call the REST resource from a client command-line window.
See Salesforce's Apex REST Code Samples for further examples on how to call your specific REST resource.

curl -H "Authorization: Bearer yourSessionId" -H "Content-Type: application/json" -d @newFolder.txt "https://yourInstance.salesforce.com/services/apexrest/sFiles/""

Note the following items from the callout above:

1. curl - See the Salesforce Developer Guide article, Using cURL, to learn more about authentication with cURL.
2. yourSessionId -  The ID of an active Salesforce session or the OAuth access token. This can be noted from the login response.
3. yourInstance - The URL for the Salesforce server you are logging into. 
4. @newFolder.txt -  If your REST method accepts parameters you will need to create a file to contain this data. In the example above, this file is "newFolder.txt" and it contains the data in the code snippet below.

{
  "parentFolderId" : "yourParentFolderId",
  "folderName" : "yourFolderName",
}